Harmonic MSUP Using the Multiple SOLVE Method

Triangle Wave by Fourier Series*

In the Ansys APDL documentation of Mode-Superposition Harmonic Analysis and other Verification Manual documentation (e.g. VM76 & VM149), only load step file method was described. Personally, I favor Multiple Solve Method instead because you can vary the loads for different frequencies. This could come in handy for different loads at various engine orders or rotating unbalance force. Or say if you have the Fourier coefficients of the periodic force of irregular form (e.g. triangle wave), the steady state response can be computed.

The APDL script below replicates VM183 but uses the Multiple Solve Method. Do let me know if you could recommend ways to improve the script.

Script
!! Modified from VM183 to use Multiple SOLVE Method
!! Results should be identical to VM183
! Author: Sze Kwan (Jason) Cheah
! Modified: August 27, 2017
! Disclaimer: Use at own risk!

/PREP7
ANTYPE, MODAL ! MODE - FREQUENCY ANALYSIS
MODOPT, LANB,2,,,
ET,1,COMBIN40,,,2 ! UY DOF
R,1,6,,2 ! K1=6 N/M M1=2 KG
R,2,16,,2 ! K2=16 N/M M2=2 KG
N,1
N,2,0,1
N,3,0,2
REAL,1
E,1,2
REAL,2
E,2,3
OUTPR,,ALL
D,3,ALL
FINISH

/SOLU
SOLVE
FINISH

/SOLU
ANTYPE, HARMIC ! HARMONIC ANALYSIS
HROPT, MSUP ! MODE SUPERPOSITION
*do, ct, 1, 50
fnow = 0.1+(1-0.1)/50*ct ! referencing array is alternative
HARFRQ, fnow
F, 1, FY, 50 ! force function can be frequency dependent
! e.g. F,1,FY,m*e*(2*3.14159*fnow)**2
KBC, 1
SOLVE
*enddo
FINISH

/SOLU
allsel
expass, on ! EXPANSION PASS
numexp, all
solve
finish

Comments

ANSYS User Defined Results

There is an abundant of options in ANSYS classic when one wishes to post process results. ANSYS workbench default pull down menu post processing options are more limited but they can still be accessed via the User Defined Results. One way not commonly used but can come in handy is as follows: Zeroth: Under Analysis Settings, there is "Output Controls" where you can toggle to "Yes" what you would like to save before the solution starts. This is like OUTRES in APDL. Output Controls First: After solving the model, click on Solution in the tree to highlight it. Solution Second: Click on Worksheet in the toolbar. Worksheet Third: In the worksheet, you will see list of results that are saved. Right click on it to create the User Defined Results. Create User Defined Results So here we have it. You could of look up the different expressions in the help document but I find this method of accessing the results convenient. Example: Aspec

Export Stiffness Matrix from Ansys

It is sometimes useful to extract the mass and stiffness matrix from Ansys. *SMAT, MatK, D, IMPORT, FULL, file.full, STIFF *PRINT, matk, matk, txt Exporting mass matrix would be similar: *SMAT, MatM, D, import, full, file.full, MASS The above script uses APDL Math to get the job done. (Please see previous post for another example). The ordering of the matrix is unfortunately not concurrently exported. To verify the sequencing is as expected, we will work to replicate a truss example in the Finite Element Trusses course notes by Bob Greenlee. Figure 1: Truss Problem Setup Model Creation Script to create model: /prep7 !! Creates Model to reflect course notes ! Properties et ,1,1 mp , ex, 1, 29.5e6 r , 1, 1 ! Geometry n ,1 $ n ,2, 40 $ n ,3, 40, 30 $ n ,4, 0, 30 e ,1,2 $ e ,2,3 $ e ,1,3 $ e ,3,4 ! Boundary Conditions d ,1,ux,0 $ d ,1,uy,0 d ,2,uy,0 d ,4,ux,0 $ d ,4,uy,0 f ,2,fx,20e3 f ,3,fy,-25e3 ! solves /solu eqslv , sparse

ANSYS APDL Syntax Highlighting editor

Notepad++ with APDL User Defined Language The editor of my choice is Notepad++ with the available User Defined Language Files for APDL . You can install it without administrative privileges via the zip file. The best part of it is, it's FREE! After installing Notepad++, go to "Language>Define Your Language..." then "Import" the XML file downloaded from the above link. Remember to restart Notepad++ so that the language changes will take into effect. Opening up any *.inp or *.ans files should automatically switch highlighting to APDL. I made some minor edits. Here's my XML file: LINK . I also heard Sublime Text and Ultraedit has more advance features but they aren't (totally) free.

Ansys Tips

Search This Blog