Skip to main content

Defining Ansys Superelement SUB File Manually

Photo by James Owen on Unsplash

A surprisingly popular blog-post written here is Exporting Stiffness Matrix from Ansys. A sensible follow up question is what can one do with the exported stiffness matrix? In a recent Xansys Forum post, a question was raised on how we can edit the stiffness matrix of a superelement and use it for our model. 

An approach presented below is to first create a superelement that has the same number of DOF and nodal location that will serve as a template. An APDL script can then be written to edit the stiffness matrix entries as desired before exporting to a new superelement *.SUB file for use in future models. The self-contained script below demonstrates this. 

et,1, 185
mp, ex, 1, 200e3
mp, prxy, 1, 0.33

w = 0.1 ! single element (note nodal locations)
n, 1, w, -w, -w
n, 2, w, w, -w
n, 3, -w, w, -w
n, 4, -w, -w, -w
n, 5, w, -w, w
n, 6, w, w, w
n, 7, -w, w, w
n, 8, -w, -w, w
e, 1, 2, 3, 4, 5, 6, 7, 8

antype, substr     ! analysis type: substructure
seopt, myse,1   ! saves stiffness matrix
m, all, all

! Imports sub info into APDL-math form
*DMAT, myse, d, import, sub, myse.sub, stiff

! Export to apdl array for editing
*EXPORT, myse, apdl, apdlmat

! Make edits as desired
apdlmat(2,2) = 28 ! example edit to be checked later

! Put back to APDL-math form
*DMAT, myse, ,import, apdl, apdlmat

! exports desired sub file
*EXPORT, myse, sub, newse.sub, stiff, , done

!! To verify it works as expected
/clear ! start from scratch 

et, 1, 50 
se, newse 

eqslv, sparse
wrfull, 1

*DMAT, MatK_check, D, import, full, file.full, stiff
*EXPORT, MatK_check, apdl, apdlmat_check
shouldbe28 = apdlmat_check(2,2)
*stat, shouldbe28

Other Resources
Matrix Transfer between MATLAB and Ansys link
Export Stiffness Matrix from Ansys link
APDL Math Example link
Ansys's Website APDL Math Example link


Popular posts from this blog

ANSYS User Defined Results

There is an abundant of options in ANSYS classic when one wishes to post process results. ANSYS workbench default pull down menu post processing options are more limited but they can still be accessed via the User Defined Results. One way not commonly used but can come in handy is as follows: Zeroth: Under Analysis Settings, there is "Output Controls" where you can toggle to "Yes" what you would like to save before the solution starts. This is like OUTRES in APDL. Output Controls First: After solving the model, click on Solution in the tree to highlight it. Solution Second: Click on Worksheet in the toolbar. Worksheet Third: In the worksheet, you will see list of results that are saved. Right click on it to create the User Defined Results. Create User Defined Results So here we have it. You could of look up the different expressions in the help document but I find this method of accessing the results convenient.  Example: Aspec

Export Stiffness Matrix from Ansys

It is sometimes useful to extract the mass and stiffness matrix from Ansys.     *SMAT, MatK, D, IMPORT, FULL, file.full, STIFF       *PRINT, matk, matk, txt Exporting mass matrix would be similar:       *SMAT, MatM, D, import, full, file.full, MASS The above script uses APDL Math to get the job done. (Please see previous post for another example). The ordering of the matrix is unfortunately not concurrently exported. To verify the sequencing is as expected, we will work to replicate a truss example in the  Finite Element Trusses course notes by Bob Greenlee. Figure 1: Truss Problem Setup Model Creation Script to create model: /prep7 !! Creates Model to reflect course notes ! Properties et ,1,1  mp , ex, 1, 29.5e6 r , 1, 1 ! Geometry n ,1 $  n ,2, 40 $  n ,3, 40, 30 $  n ,4, 0, 30 e ,1,2 $  e ,2,3 $  e ,1,3 $  e ,3,4 ! Boundary Conditions d ,1,ux,0 $  d ,1,uy,0 d ,2,uy,0 d ,4,ux,0 $  d ,4,uy,0 f ,2,fx,20e3 f ,3,fy,-25e3 ! solves /solu eqslv , sparse

ANSYS APDL Syntax Highlighting editor

Notepad++ with APDL User Defined Language The editor of my choice is Notepad++  with the available User Defined Language Files for APDL . You can install it without administrative privileges via the zip file. The best part of it is, it's FREE! After installing Notepad++, go to "Language>Define Your Language..." then "Import" the XML file downloaded from the above link. Remember to restart Notepad++ so that the language changes will take into effect. Opening up any *.inp or *.ans files should automatically switch highlighting to APDL. I made some minor edits. Here's my XML file: LINK . I also heard Sublime Text and  Ultraedit  has more advance features but they aren't (totally) free.